Add mix debug mode. Close #4106.

Author: Daniel Perez

lib/mix/lib/mix.ex

@@ -234,6 +234,20 @@ defmodule Mix do
     Mix.State.put(:shell, shell)
   end
 
+  @doc """
+  Returns true if Mix is in debug mode.
+  """
+  def debug? do
+    Mix.State.get(:debug, false)
+  end
+
+  @doc """
+  Sets Mix debug mode.
+  """
+  def debug(debug) when is_boolean(debug) do
+    Mix.State.put(:debug, debug)
+  end
+
   @doc """
   Raises a Mix error that is nicely formatted.
   """

lib/mix/lib/mix/cli.ex

@@ -8,7 +8,8 @@ defmodule Mix.CLI do
     Mix.Local.append_archives
     Mix.Local.append_paths
 
-    if System.get_env("MIX_QUIET"), do: Mix.shell(Mix.Shell.Quiet)
+    if env_variable_activated?("MIX_QUIET"), do: Mix.shell(Mix.Shell.Quiet)
+    if env_variable_activated?("MIX_DEBUG"), do: Mix.debug(true)
 
     case check_for_shortcuts(args) do
       :help ->
@@ -71,6 +72,10 @@ defmodule Mix.CLI do
     end
   end
 
+  defp env_variable_activated?(name) do
+    System.get_env(name) in ~w(1 true)
+  end
+
   defp ensure_hex("local.hex"),
     do: :ok
   defp ensure_hex(_task),

lib/mix/lib/mix/task.ex

@@ -250,6 +250,8 @@ defmodule Mix.Task do
   end
 
   defp run_task(proj, task, args) do
+    if Mix.debug?, do: output_task_debug_info(task, args, proj)
+
     # 1. If the task is available, we run it.
     # 2. Otherwise we look for it in dependencies.
     # 3. Finally, we compile the current project in hope it is available.
@@ -275,6 +277,16 @@ defmodule Mix.Task do
     end
   end
 
+  defp output_task_debug_info(task, args, proj) do
+    Mix.shell.info("** Running mix " <> task_to_string(task, args) <> project_to_string(proj))
+  end
+
+  defp project_to_string(nil), do: ""
+  defp project_to_string(proj), do: " (inside #{inspect proj})"
+
+  defp task_to_string(task, []), do: task
+  defp task_to_string(task, args), do: task <> " " <> Enum.join(args, " ")
+
   defp deps_loadpaths do
     Mix.Task.run "deps.check"
     Mix.Task.run "deps.loadpaths"

lib/mix/test/mix/cli_test.exs

@@ -52,6 +52,15 @@ defmodule Mix.CLITest do
 
       assert contents =~ "Hello from MyProject!\n"
       refute contents =~ "This won't appear"
+
+      contents = mix ~w[my_hello], [{"MIX_QUIET", "0"}]
+      assert contents =~ "This won't appear"
+
+      contents = mix ~w[my_hello], [{"MIX_DEBUG", "1"}]
+      assert contents =~ "** Running mix my_hello (inside MyProject)"
+
+      contents = mix ~w[my_hello], [{"MIX_DEBUG", "0"}]
+      refute contents =~ "** Running mix my_hello (inside MyProject)"
     end
   end
 
@@ -132,7 +141,7 @@ defmodule Mix.CLITest do
   defp mix(args, envs \\ []) when is_list(args) do
     System.cmd(elixir_executable,
                ["-r", mix_executable, "--"|args],
-               stderr_to_stdout: true, 
+               stderr_to_stdout: true,
                env: envs) |> elem(0)
   end
 

lib/mix/test/mix/task_test.exs

@@ -26,6 +26,17 @@ defmodule Mix.TaskTest do
     end
   end
 
+  test "output task debug info if Mix.debug? is true" do
+    Mix.shell Mix.Shell.IO
+    Mix.debug(true)
+
+    assert ExUnit.CaptureIO.capture_io(fn -> Mix.Task.run("hello") end) =~
+      "** Running mix hello"
+  after
+    Mix.shell(Mix.Shell.Process)
+    Mix.debug(false)
+  end
+
   test "try to deps.loadpaths if task is missing", context do
     in_tmp context.test, fn ->
       Mix.Project.push(SampleProject, "sample")

lib/mix/test/mix_test.exs

@@ -12,4 +12,11 @@ defmodule MixTest do
     Mix.env(:prod)
     assert Mix.env == :prod
   end
-end
+
+  test "debug" do
+    refute Mix.debug?
+    Mix.debug(true)
+    assert Mix.debug?
+    Mix.debug(false)
+  end
+end

man/mix.1

@@ -65,6 +65,8 @@ Allows specifying the directory into which the archives should be installed
 The
 .Em ~/.mix/archives
 directory is used for this purpose by default.
+.It Ev MIX_DEBUG
+When set, outputs debug information about each task before running it.
 .It Ev MIX_ENV
 Allows specifying which environment should be used. The
 .Em dev