Merge pull request #1660 from betawaffle/enum-concat

Add Stream.concat/1,2 and Enum.concat/1,2

Author: José Valim

lib/elixir/lib/enum.ex

@@ -221,6 +221,52 @@ defmodule Enum do
     end
   end
 
+  @doc """
+  Given an enumerable of enumerables, concatenate the enumerables into a single list.
+
+  ## Examples
+
+      iex> Enum.concat([1..3, 4..6, 7..9])
+      [1,2,3,4,5,6,7,8,9]
+
+      iex> Enum.concat([[1, [2], 3], [4], [5, 6]])
+      [1,[2],3,4,5,6]
+
+  """
+  @spec concat(t) :: t
+  def concat(enumerables) do
+    do_concat(enumerables)
+  end
+
+  @doc """
+  Concatenates the enumerable on the right with the enumerable on the left.
+
+  This function produces the same result the `++` operator for lists.
+
+  ## Examples
+
+      iex> Enum.concat(1..3, 4..6)
+      [1,2,3,4,5,6]
+
+      iex> Enum.concat([1, 2, 3], [4, 5, 6])
+      [1,2,3,4,5,6]
+
+  """
+  @spec concat(t, t) :: t
+  def concat(left, right) when is_list(left) and is_list(right) do
+    left ++ right
+  end
+
+  def concat(left, right) do
+    do_concat([left, right])
+  end
+
+  defp do_concat(enumerable, acc // []) do
+    fun = &[&1|&2]
+    Enumerable.reduce(enumerable, acc, &Enumerable.reduce(&1, &2, fun))
+      |> :lists.reverse
+  end
+
   @doc """
   Drops the first `count` items from `collection`.
   Expects an ordered collection.

lib/elixir/lib/kernel/cli.ex

@@ -342,7 +342,7 @@ defmodule Kernel.CLI do
     :filelib.ensure_dir(:filename.join(config.output, "."))
 
     files = Enum.map patterns, Path.wildcard(&1)
-    files = Enum.uniq(List.concat(files))
+    files = Enum.uniq(Enum.concat(files))
     files = Enum.filter files, :filelib.is_regular(&1)
 
     if files != [] do

lib/elixir/lib/list.ex

@@ -12,31 +12,15 @@ defmodule List do
 
   @compile :inline_list_funcs
 
-  @doc """
-  Given a list of lists, concatenate the sublists into a single list.
-
-  ## Examples
-
-      iex> List.concat([[1, [2], 3], [4], [5, 6]])
-      [1,[2],3,4,5,6]
-
-  """
+  @doc false
   def concat(list) when is_list(list) do
+    IO.write "List.concat/1 is deprecated, please use Enum.concat/1 instead\n#{Exception.format_stacktrace}"
     :lists.append(list)
   end
 
-  @doc """
-  Concatenates the list on the right with the list on the left.
-
-  This function produces the same result the `++` operator. 
-
-  ## Examples
-
-      iex> List.concat([1, 2, 3], [4, 5, 6])
-      [1,2,3,4,5,6]
-
-  """
+  @doc false
   def concat(list, elements) when is_list(list) and is_list(elements) do
+    IO.write "List.concat/2 is deprecated, please use Enum.concat/2 instead\n#{Exception.format_stacktrace}"
     list ++ elements
   end
 

lib/elixir/lib/stream.ex

@@ -131,6 +131,46 @@ defmodule Stream do
   @type index :: non_neg_integer
   @type default :: any
 
+  @doc """
+  Creates a stream that enumerates each enumerable in an enumerable.
+
+  ## Examples
+
+      iex> stream = Stream.concat([1..3, 4..6, 7..9])
+      iex> Enum.to_list(stream)
+      [1,2,3,4,5,6,7,8,9]
+
+  """
+  @spec concat(Enumerable.t) :: t
+  def concat(enumerables) do
+    &do_concat(enumerables, &1, &2)
+  end
+
+  @doc """
+  Creates a stream that enumerates the first argument, followed by the second.
+
+  ## Examples
+
+      iex> stream = Stream.concat(1..3, 4..6)
+      iex> Enum.to_list(stream)
+      [1,2,3,4,5,6]
+
+      iex> stream1 = Stream.cycle([1, 2, 3])
+      iex> stream2 = Stream.cycle([4, 5, 6])
+      iex> stream = Stream.concat(stream1, stream2)
+      iex> Enum.take(stream, 6)
+      [1,2,3,1,2,3]
+
+  """
+  @spec concat(Enumerable.t, Enumerable.t) :: t
+  def concat(first, second) do
+    &do_concat([first, second], &1, &2)
+  end
+
+  defp do_concat(enumerables, acc, fun) do
+    Enumerable.reduce(enumerables, acc, &Enumerable.reduce(&1, &2, fun))
+  end
+
   @doc """
   Creates a stream that cycles through the given enumerable,
   infinitely.

lib/elixir/test/elixir/enum_test.exs

@@ -54,6 +54,27 @@ defmodule EnumTest.List do
     assert Enum.at([2, 4, 6], 4, :none) == :none
   end
 
+  test :concat_1 do
+    assert Enum.concat([[1, [2], 3], [4], [5, 6]]) == [1, [2], 3, 4, 5, 6]
+    assert Enum.concat(1..3, []) == [1,2,3]
+
+    assert Enum.concat([[], []]) == []
+    assert Enum.concat([[]])     == []
+    assert Enum.concat([])       == []
+
+    assert Enum.concat([1..5, fn acc, _ -> acc end, [1]]) == [1,2,3,4,5,1]
+  end
+
+  test :concat_2 do
+    assert Enum.concat([], [1]) == [1]
+    assert Enum.concat([1, [2], 3], [4, 5]) == [1, [2], 3, 4, 5]
+    assert Enum.concat(1..3, []) == [1,2,3]
+
+    assert Enum.concat([], []) == []
+
+    assert Enum.concat(fn acc, _ -> acc end, [1]) == [1]
+  end
+
   test :fetch! do
     assert Enum.fetch!([2, 4, 6], 0) == 2
     assert Enum.fetch!([2, 4, 6], 2) == 6

lib/elixir/test/elixir/list_test.exs

@@ -53,14 +53,6 @@ defmodule ListTest do
     assert List.foldr([1, 2, 3, 4], 0, fn x, y -> x - y end) == -2
   end
 
-  test :concat_1 do
-    assert List.concat([[1, [2], 3], [4], [5, 6]]) == [1, [2], 3, 4, 5, 6]
-  end
-
-  test :concat_2 do
-    assert List.concat([1, [2], 3], [4, 5]) == [1, [2], 3, 4, 5]
-  end
-
   test :reverse do
     assert Enum.reverse([1, 2, 3]) == [3, 2, 1]
   end

lib/elixir/test/elixir/stream_test.exs

@@ -25,6 +25,37 @@ defmodule StreamTest do
     assert Enum.to_list(stream) == [3,5,7]
   end
 
+  test :concat_1 do
+    stream = Stream.concat([1..3, [], [4, 5, 6], [], 7..9])
+    assert is_function(stream)
+
+    assert Enum.to_list(stream) == [1,2,3,4,5,6,7,8,9]
+    assert Enum.take(stream, 5) == [1,2,3,4,5]
+
+    stream = Stream.concat([1..3, [4, 5, 6], Stream.cycle(7..100)])
+    assert is_function(stream)
+
+    assert Enum.take(stream, 13) == [1,2,3,4,5,6,7,8,9,10,11,12,13]
+  end
+
+  test :concat_2 do
+    stream = Stream.concat(1..3, 4..6)
+    assert is_function(stream)
+    assert Stream.cycle(stream) |> Enum.take(16) == [1,2,3,4,5,6,1,2,3,4,5,6,1,2,3,4]
+
+    stream = Stream.concat(1..3, [])
+    assert is_function(stream)
+    assert Stream.cycle(stream) |> Enum.take(5) == [1,2,3,1,2]
+
+    stream = Stream.concat(1..6, Stream.cycle(7..9))
+    assert is_function(stream)
+    assert Stream.drop(stream, 3) |> Enum.take(13) == [4,5,6,7,8,9,7,8,9,7,8,9,7]
+
+    stream = Stream.concat(Stream.cycle(1..3), Stream.cycle(4..6))
+    assert is_function(stream)
+    assert Enum.take(stream, 13) == [1,2,3,1,2,3,1,2,3,1,2,3,1]
+  end
+
   test :cycle do
     stream = Stream.cycle([1,2,3])
     assert is_function(stream)

lib/ex_unit/lib/ex_unit/doc_test.ex

@@ -311,7 +311,7 @@ defmodule ExUnit.DocTest do
 
     docs = lc doc inlist module.__info__(:docs) do
       extract_from_doc(doc)
-    end |> List.concat
+    end |> Enum.concat
 
     moduledocs ++ docs
   end

lib/iex/lib/iex/introspection.ex

@@ -254,7 +254,7 @@ defmodule IEx.Introspection do
   defp beam_specs(module) do
     specs = Enum.map(Kernel.Typespec.beam_specs(module), {:spec, &1})
     callbacks = Enum.map(Kernel.Typespec.beam_callbacks(module), {:callback, &1})
-    List.concat(specs, callbacks)
+    Enum.concat(specs, callbacks)
   end
 
   defp print_type({ kind, type }) do

lib/mix/lib/mix/deps.ex

@@ -322,7 +322,7 @@ defmodule Mix.Deps do
 
     [ opts[:dest] | sub_dirs ]
       |> Enum.map(Path.wildcard(&1))
-      |> List.concat
+      |> Enum.concat
       |> Enum.map(Path.join(&1, "ebin"))
       |> Enum.filter(File.dir?(&1))
   end