Add Enum.slice/3

Author: ericmj

lib/elixir/lib/enum.ex

@@ -1303,6 +1303,38 @@ defmodule Enum do
     end
   end
 
+  @doc """
+  Returns a subset list of the given collection. Dropping elements
+  until element position `start`, then taking `count` elements.
+  Expects an ordered collection.
+  """
+  @spec slice(t, integer, integer) :: list
+
+  def slice(_coll, _start, 0), do: []
+
+  def slice(coll, start, count) when is_list(coll) and start >= 0 do
+    do_slice(coll, start, count)
+  end
+
+  def slice(coll, start, count) when start >= 0 do
+    { _, _, list } = Enumerable.reduce(coll, { start, count, [] }, fn
+      _entry, { start, count, _list } when start > 0 ->
+        { start-1, count, [] }
+      entry, { start, count, list } when count > 1 ->
+        { start, count-1, [entry|list] }
+      entry, { _start, _count, list } ->
+        throw { :enum_slice, [entry|list] }
+    end)
+    :lists.reverse(list)
+  catch
+    { :enum_slice, list } -> :lists.reverse(list)
+  end
+
+  def slice(coll, start, count) when start < 0 do
+    { list, start } = iterate_and_count(coll, start)
+    slice(list, start, count)
+  end
+
   ## Helpers
 
   @compile { :inline, chunks_n: 5, chunks_step: 4, to_string: 2 }
@@ -1645,6 +1677,20 @@ defmodule Enum do
 
   defp do_zip_next([h|t]), do: { h, t }
   defp do_zip_next([]),    do: { nil, [] }
+
+  ## slice
+
+  defp do_slice([], _start, _count), do: []
+
+  defp do_slice(_list, _start, 0), do: []
+
+  defp do_slice([h|t], 0, count) do
+    [h|do_slice(t, 0, count-1)]
+  end
+
+  defp do_slice([_|t], start, count) do
+    do_slice(t, start-1, count)
+  end
 end
 
 defimpl Enumerable, for: List do

lib/elixir/test/elixir/enum_test.exs

@@ -311,6 +311,18 @@ defmodule EnumTest.List do
     assert Enum.chunks_by([], fn _ -> true end) == []
     assert Enum.chunks_by([1], fn _ -> true end) == [[1]]
   end
+
+  test :slice do
+    assert Enum.slice([1,2,3,4,5], 0, 0) == []
+    assert Enum.slice([1,2,3,4,5], 0, 1) == [1]
+    assert Enum.slice([1,2,3,4,5], 0, 2) == [1, 2]
+    assert Enum.slice([1,2,3,4,5], 1, 2) == [2, 3]
+    assert Enum.slice([1,2,3,4,5], 1, 0) == []
+    assert Enum.slice([1,2,3,4,5], 2, 5) == [3, 4, 5]
+    assert Enum.slice([1,2,3,4,5], 5, 5) == []
+    assert Enum.slice([1,2,3,4,5], -2, 5) == [4, 5]
+    assert Enum.slice([1,2,3,4,5], -3, 1) == [3]
+  end
 end
 
 defmodule EnumTest.Range do
@@ -653,6 +665,18 @@ defmodule EnumTest.Range do
     assert Enum.chunks_by(1..4, fn _ -> true end) == [[1, 2, 3, 4]]
     assert Enum.chunks_by(1..4, &(rem(&1, 2) == 1)) == [[1], [2], [3], [4]]
   end
+
+  test :slice do
+    assert Enum.slice(1..5, 0, 0) == []
+    assert Enum.slice(1..5, 0, 1) == [1]
+    assert Enum.slice(1..5, 0, 2) == [1, 2]
+    assert Enum.slice(1..5, 1, 2) == [2, 3]
+    assert Enum.slice(1..5, 1, 0) == []
+    assert Enum.slice(1..5, 2, 5) == [3, 4, 5]
+    assert Enum.slice(1..5, 5, 5) == []
+    assert Enum.slice(1..5, -2, 5) == [4, 5]
+    assert Enum.slice(1..5, -3, 1) == [3]
+  end
 end
 
 defmodule EnumTest.Others do