Case insensitive module resolution (#12007)

Author: sabiwara

lib/elixir/lib/code.ex

@@ -1706,8 +1706,8 @@ defmodule Code do
   def fetch_docs(module_or_path)
 
   def fetch_docs(module) when is_atom(module) do
-    case :code.get_object_code(module) do
-      {_module, bin, beam_path} ->
+    case get_beam_and_path(module) do
+      {bin, beam_path} ->
         case fetch_docs_from_beam(bin) do
           {:error, :chunk_not_found} ->
             app_root = Path.expand(Path.join(["..", ".."]), beam_path)
@@ -1742,6 +1742,15 @@ defmodule Code do
     fetch_docs_from_beam(String.to_charlist(path))
   end
 
+  defp get_beam_and_path(module) do
+    with {^module, beam, filename} <- :code.get_object_code(module),
+         {:ok, ^module} <- beam |> :beam_lib.info() |> Keyword.fetch(:module) do
+      {beam, filename}
+    else
+      _ -> :error
+    end
+  end
+
   @docs_chunk 'Docs'
 
   defp fetch_docs_from_beam(bin_or_path) do

lib/elixir/lib/code/typespec.ex

@@ -174,9 +174,11 @@ defmodule Code.Typespec do
   end
 
   defp get_module_and_beam(module) when is_atom(module) do
-    case :code.get_object_code(module) do
-      {^module, beam, _filename} -> {module, beam}
-      :error -> :error
+    with {^module, beam, _filename} <- :code.get_object_code(module),
+         {:ok, ^module} <- beam |> :beam_lib.info() |> Keyword.fetch(:module) do
+      {module, beam}
+    else
+      _ -> :error
     end
   end
 

lib/elixir/lib/module/parallel_checker.ex

@@ -317,6 +317,7 @@ defmodule Module.ParallelChecker do
 
   defp cache_from_chunk(ets, module) do
     with {^module, binary, _filename} <- :code.get_object_code(module),
+         {:ok, ^module} <- binary |> :beam_lib.info() |> Keyword.fetch(:module),
          {:ok, {_, [{'ExCk', chunk}]}} <- :beam_lib.chunks(binary, ['ExCk']),
          {:elixir_checker_v1, contents} <- :erlang.binary_to_term(chunk) do
       cache_chunk(ets, module, contents.exports)

lib/elixir/test/elixir/code_test.exs

@@ -311,6 +311,17 @@ defmodule CodeTest do
       Code.put_compiler_option(:debug_info, :not_a_boolean)
     end
   end
+
+  describe "fetch_docs/1" do
+    test "is case sensitive" do
+      assert {:docs_v1, _, :elixir, _, %{"en" => module_doc}, _, _} = Code.fetch_docs(IO)
+
+      assert "Functions handling input/output (IO)." =
+               module_doc |> String.split("\n") |> Enum.at(0)
+
+      assert Code.fetch_docs(Io) == {:error, :module_not_found}
+    end
+  end
 end
 
 defmodule Code.SyncTest do

lib/elixir/test/elixir/module/types/integration_test.exs

@@ -201,6 +201,8 @@ defmodule Module.Types.IntegrationTest do
 
           @file "external_source.ex"
           def c, do: E.no_module()
+
+          def i, do: Io.puts "hello"
         end
         """
       }
@@ -212,6 +214,9 @@ defmodule Module.Types.IntegrationTest do
       warning: E.no_module/0 is undefined (module E is not available or is yet to be defined)
         external_source.ex:5: A.c/0
 
+      warning: Io.puts/1 is undefined (module Io is not available or is yet to be defined)
+        a.ex:7: A.i/0
+
       """
 
       assert_warnings(files, warning)

lib/iex/lib/iex/helpers.ex

@@ -1371,8 +1371,8 @@ defmodule IEx.Helpers do
 
   """
   def nl(nodes \\ Node.list(), module) when is_list(nodes) and is_atom(module) do
-    case :code.get_object_code(module) do
-      {^module, bin, beam_path} ->
+    case get_beam_and_path(module) do
+      {bin, beam_path} ->
         results =
           for node <- nodes do
             case :rpc.call(node, :code, :load_binary, [module, beam_path, bin]) do
@@ -1389,4 +1389,13 @@ defmodule IEx.Helpers do
         {:error, :nofile}
     end
   end
+
+  defp get_beam_and_path(module) do
+    with {^module, beam, filename} <- :code.get_object_code(module),
+         {:ok, ^module} <- beam |> :beam_lib.info() |> Keyword.fetch(:module) do
+      {beam, filename}
+    else
+      _ -> :error
+    end
+  end
 end