Convert Mix.State to a process and use better storage

* Use ETS instead of going through an Agent

* Use persistent_term for long term storage

Author: josevalim

lib/mix/lib/mix/scm.ex

@@ -128,21 +128,20 @@ defmodule Mix.SCM do
   until a matching one is found.
   """
   def available do
-    {:ok, scm} = Mix.State.fetch(:scm)
-    scm
+    Mix.State.get(:scm)
   end
 
   @doc """
   Prepends the given SCM module to the list of available SCMs.
   """
   def prepend(mod) when is_atom(mod) do
-    Mix.State.prepend_scm(mod)
+    Mix.State.update(:scm, &[mod | List.delete(&1, mod)])
   end
 
   @doc """
   Appends the given SCM module to the list of available SCMs.
   """
   def append(mod) when is_atom(mod) do
-    Mix.State.append_scm(mod)
+    Mix.State.update(:scm, &(List.delete(&1, mod) ++ [mod]))
   end
 end

lib/mix/lib/mix/scm/git.ex

@@ -67,7 +67,6 @@ defmodule Mix.SCM.Git do
 
   @impl true
   def lock_status(opts) do
-    assert_git!()
     lock = opts[:lock]
 
     cond do
@@ -102,7 +101,6 @@ defmodule Mix.SCM.Git do
 
   @impl true
   def checkout(opts) do
-    assert_git!()
     path = opts[:checkout]
     File.rm_rf!(path)
     File.mkdir_p!(opts[:dest])
@@ -116,7 +114,6 @@ defmodule Mix.SCM.Git do
 
   @impl true
   def update(opts) do
-    assert_git!()
     path = opts[:checkout]
     File.cd!(path, fn -> checkout(path, opts) end)
   end
@@ -286,7 +283,17 @@ defmodule Mix.SCM.Git do
   defp git!(args, into \\ default_into()) do
     opts = cmd_opts(into: into, stderr_to_stdout: true)
 
-    case System.cmd("git", args, opts) do
+    try do
+      System.cmd("git", args, opts)
+    catch
+      :error, :enoent ->
+        Mix.raise(
+          "Error fetching/updating Git repository: the \"git\" " <>
+            "executable is not available in your PATH. Please install " <>
+            "Git on this machine or pass --no-deps-check if you want to " <>
+            "run a previously built application on a system without Git."
+        )
+    else
       {response, 0} ->
         response
 
@@ -305,25 +312,18 @@ defmodule Mix.SCM.Git do
     end
   end
 
-  defp assert_git! do
-    case Mix.State.fetch(:git_available) do
-      {:ok, true} ->
-        :ok
-
-      :error ->
-        if System.find_executable("git") do
-          Mix.State.put(:git_available, true)
-        else
-          Mix.raise(
-            "Error fetching/updating Git repository: the \"git\" " <>
-              "executable is not available in your PATH. Please install " <>
-              "Git on this machine or pass --no-deps-check if you want to " <>
-              "run a previously built application on a system without Git."
-          )
-        end
+  # Attempt to set the current working directory by default.
+  # This addresses an issue changing the working directory when executing from
+  # within a secondary node since file I/O is done through the main node.
+  defp cmd_opts(opts) do
+    case File.cwd() do
+      {:ok, cwd} -> Keyword.put(opts, :cd, cwd)
+      _ -> opts
     end
   end
 
+  # Also invoked by lib/mix/test/test_helper.exs
+  @doc false
   def git_version do
     case Mix.State.fetch(:git_version) do
       {:ok, version} ->
@@ -333,7 +333,7 @@ defmodule Mix.SCM.Git do
         version =
           ["--version"]
           |> git!("")
-          |> parse_version
+          |> parse_version()
 
         Mix.State.put(:git_version, version)
         version
@@ -352,14 +352,4 @@ defmodule Mix.SCM.Git do
     {int, _} = Integer.parse(string)
     int
   end
-
-  # Attempt to set the current working directory by default.
-  # This addresses an issue changing the working directory when executing from
-  # within a secondary node since file I/O is done through the main node.
-  defp cmd_opts(opts) do
-    case File.cwd() do
-      {:ok, cwd} -> Keyword.put(opts, :cd, cwd)
-      _ -> opts
-    end
-  end
 end

lib/mix/lib/mix/state.ex

@@ -1,22 +1,25 @@
 defmodule Mix.State do
   @moduledoc false
   @name __MODULE__
-  @timeout :infinity
 
-  use Agent
+  use GenServer
 
   def start_link(_opts) do
-    Agent.start_link(__MODULE__, :init, [], name: @name)
+    GenServer.start_link(__MODULE__, :ok, name: @name)
   end
 
-  def init() do
-    %{
+  @impl true
+  def init(:ok) do
+    table = :ets.new(@name, [:public, :set, :named_table, read_concurrency: true])
+
+    :ets.insert(table,
       shell: Mix.Shell.IO,
       env: from_env("MIX_ENV", :dev),
       target: from_env("MIX_TARGET", :host),
-      scm: [Mix.SCM.Git, Mix.SCM.Path],
-      cache: :ets.new(@name, [:public, :set, :named_table, read_concurrency: true])
-    }
+      scm: [Mix.SCM.Git, Mix.SCM.Path]
+    )
+
+    {:ok, table}
   end
 
   defp from_env(varname, default) do
@@ -28,50 +31,43 @@ defmodule Mix.State do
   end
 
   def fetch(key) do
-    Agent.get(@name, Map, :fetch, [key], @timeout)
+    case :ets.lookup(@name, key) do
+      [{^key, value}] -> {:ok, value}
+      [] -> :error
+    end
   end
 
   def get(key, default \\ nil) do
-    Agent.get(@name, Map, :get, [key, default], @timeout)
+    case :ets.lookup(@name, key) do
+      [{^key, value}] -> value
+      [] -> default
+    end
   end
 
   def put(key, value) do
-    Agent.update(@name, Map, :put, [key, value], @timeout)
-  end
-
-  def prepend_scm(value) do
-    Agent.update(
-      @name,
-      fn state -> update_in(state.scm, &[value | List.delete(&1, value)]) end,
-      @timeout
-    )
+    :ets.insert(@name, {key, value})
   end
 
-  def append_scm(value) do
-    Agent.update(
-      @name,
-      fn state -> update_in(state.scm, &(List.delete(&1, value) ++ [value])) end,
-      @timeout
-    )
+  def update(key, fun) do
+    :ets.insert(@name, {key, fun.(:ets.lookup_element(@name, key, 2))})
   end
 
   def read_cache(key) do
-    case :ets.lookup(@name, key) do
-      [{^key, value}] -> value
-      [] -> nil
-    end
+    :persistent_term.get({__MODULE__, key}, nil)
   end
 
   def write_cache(key, value) do
-    :ets.insert(@name, {key, value})
+    :persistent_term.put({__MODULE__, key}, value)
     value
   end
 
   def delete_cache(key) do
-    :ets.delete(@name, key)
+    :persistent_term.erase({__MODULE__, key})
   end
 
   def clear_cache do
-    :ets.delete_all_objects(@name)
+    for {{__MODULE__, _} = key, _value} <- :persistent_term.get() do
+      :persistent_term.erase(key)
+    end
   end
 end

lib/mix/lib/mix/tasks_server.ex

@@ -1,35 +1,33 @@
 defmodule Mix.TasksServer do
   @moduledoc false
   @name __MODULE__
-  @timeout :infinity
 
   use Agent
 
   def start_link(_opts) do
-    Agent.start_link(fn -> %{} end, name: @name)
+    Agent.start_link(
+      fn -> :ets.new(@name, [:public, :set, :named_table]) end,
+      name: @name
+    )
   end
 
   def run(tuple) do
-    Agent.get_and_update(
-      @name,
-      fn set -> {not Map.has_key?(set, tuple), Map.put(set, tuple, true)} end,
-      @timeout
-    )
+    :ets.insert_new(@name, {tuple})
   end
 
   def put(tuple) do
-    Agent.update(@name, &Map.put(&1, tuple, true), @timeout)
+    :ets.insert(@name, {tuple})
   end
 
   def get(tuple) do
-    Agent.get(@name, &Map.get(&1, tuple), @timeout)
+    :ets.member(@name, tuple)
   end
 
   def delete_many(many) do
-    Agent.update(@name, &Map.drop(&1, many), @timeout)
+    Enum.each(many, &:ets.delete(@name, &1))
   end
 
   def clear() do
-    Agent.update(@name, fn _ -> %{} end, @timeout)
+    :ets.delete_all_objects(@name)
   end
 end

lib/mix/test/mix/task_test.exs

@@ -94,7 +94,7 @@ defmodule Mix.TaskTest do
       """)
 
       # Clean up the tasks and update task
-      Mix.TasksServer.clear()
+      Mix.Task.clear()
 
       # Task was found from deps loadpaths
       assert Mix.Task.run("task_hello") == "Hello World v1"
@@ -103,7 +103,7 @@ defmodule Mix.TaskTest do
       assert Mix.Task.run("compile") != :noop
 
       # Clean up the tasks and update task
-      Mix.TasksServer.clear()
+      Mix.Task.clear()
 
       File.write!("custom/raw_repo/lib/task_hello.ex", """
       defmodule Mix.Tasks.TaskHello do