Raise compile errors on bad range types

Both sides of the range must be integers (after expansion), and
the "first" value must be greater than the "last" value.

These checks were previously performed by erl_lint.

Author: fertapric

lib/elixir/lib/kernel/typespec.ex

@@ -588,9 +588,12 @@ defmodule Kernel.Typespec do
   end
 
   # Handle ranges
-  defp typespec({:.., meta, args}, vars, caller, state) do
-    {args, state} = Enum.map_reduce(args, state, &typespec(&1, vars, caller, &2))
-    {{:type, line(meta), :range, args}, state}
+  defp typespec({:.., meta, [left, right]}, vars, caller, state) do
+    {left, state} = typespec(left, vars, caller, state)
+    {right, state} = typespec(right, vars, caller, state)
+    :ok = validate_range(left, right, caller)
+
+    {{:type, line(meta), :range, [left, right]}, state}
   end
 
   # Handle special forms
@@ -874,6 +877,26 @@ defmodule Kernel.Typespec do
     compile_error(caller, "unexpected list in typespec: #{Macro.to_string(original)}")
   end
 
+  defp validate_range({:op, _, :-, {:integer, meta, first}}, last, caller) do
+    validate_range({:integer, meta, -first}, last, caller)
+  end
+
+  defp validate_range(first, {:op, _, :-, {:integer, meta, last}}, caller) do
+    validate_range(first, {:integer, meta, -last}, caller)
+  end
+
+  defp validate_range({:integer, _, first}, {:integer, _, last}, _caller) when first < last do
+    :ok
+  end
+
+  defp validate_range(_, _, caller) do
+    message =
+      "invalid range specification, expected both sides to be integers, " <>
+        "with the left side lower than the right side"
+
+    compile_error(caller, message)
+  end
+
   defp fn_args(meta, args, return, vars, caller, state) do
     {fun_args, state} = fn_args(meta, args, vars, caller, state)
     {spec, state} = typespec(return, vars, caller, state)

lib/elixir/test/elixir/typespec_test.exs

@@ -377,11 +377,25 @@ defmodule TypespecTest do
     test "@type with a range op" do
       bytecode =
         test_module do
-          @type my_type :: 1..10
+          @type range1 :: 1..10
+          @type range2 :: -1..1
         end
 
-      assert [type: {:my_type, {:type, _, :range, [{:integer, _, 1}, {:integer, _, 10}]}, []}] =
-               types(bytecode)
+      assert [
+               {:type, {:range1, {:type, _, :range, range1_args}, []}},
+               {:type, {:range2, {:type, _, :range, range2_args}, []}}
+             ] = types(bytecode)
+
+      assert [{:integer, _, 1}, {:integer, _, 10}] = range1_args
+      assert [{:op, _, :-, {:integer, _, 1}}, {:integer, _, 1}] = range2_args
+    end
+
+    test "@type with invalid range" do
+      assert_raise CompileError, ~r"invalid range specification", fn ->
+        test_module do
+          @type my_type :: atom..10
+        end
+      end
     end
 
     test "@type with a keyword map" do