Reimplement =~ to use Regex.match? or String.contains?

Author: alco

lib/elixir/lib/kernel.ex

@@ -2814,21 +2814,51 @@ defmodule Kernel do
   defmacro left in right
 
   @doc """
-  Matches the term on the left against the regular expression
-  on the right. It returns nil if not match happened or the
-  first match otherwise.
+  Matches the term on the left against the regular expression or string on the
+  right. Returns true if `left` matches `right` (if it's a regular expression)
+  or contains `right` (if it's a string).
 
   ## Examples
 
       iex> "abcd" =~ %r/c(d)/
-      2
+      true
+
       iex> "abcd" =~ %r/e/
-      nil
+      false
+
+      iex> "abcd" =~ "bc"
+      true
+
+      iex> "abcd" =~ "ad"
+      false
 
   """
+  # fast path for literal binaries
+  defmacro left =~ right when is_binary(right) do
+    quote do
+      String.contains?(unquote(left), unquote(right))
+    end
+  end
+
+  # fast path for literal binaries
+  defmacro left =~ ({:<<>>, _, [_bin]} = right) do
+    quote do
+      String.contains?(unquote(left), unquote(right))
+    end
+  end
+
+  # slow path for everything else
   defmacro left =~ right do
     quote do
-      Regex.index(unquote(right), unquote(left))
+      str = unquote(left)
+      case unquote(right) do
+        bin when is_binary(bin) ->
+          String.contains?(str, bin)
+        re when is_regex(re) ->
+          Regex.match?(re, str)
+        other ->
+          raise ArgumentError, message: "bad argument on the right side of =~: #{inspect other}"
+      end
     end
   end
 

lib/elixir/test/elixir/kernel_test.exs

@@ -4,8 +4,24 @@ defmodule KernelTest do
   use ExUnit.Case, async: true
 
   test :match do
-    assert "abcd" =~ %r/c(d)/
-    refute "abcd" =~ %r/e/
+    assert ("abcd" =~ %r/c(d)/) == true
+    assert ("abcd" =~ %r/e/) == false
+
+    string = "^ab+cd*$"
+    assert (string =~ "ab+") == true
+    assert (string =~ "bb") == false
+
+    assert_raise ArgumentError, "bad argument on the right side of =~: [\"^a\",\"*$\"]", fn ->
+      string =~ ["^a", "*$"]
+    end
+
+    assert_raise ArgumentError, "argument error", fn ->
+      1234 =~ "hello"
+    end
+
+    assert_raise ArgumentError, "argument error", fn ->
+      1234 =~ %r"hello"
+    end
   end
 
   test :nil? do

lib/elixir/test/elixir/regex_test.exs

@@ -40,7 +40,7 @@ defmodule Regex.BinaryTest do
   end
 
   test :unicode do
-    assert ("josé" =~ %r"\p{Latin}$"u) == 3
+    assert ("josé" =~ %r"\p{Latin}$"u)
   end
 
   test :groups do