Python: Fix several bad getScope joins

It seems the optimiser has started getting the wrong end of the stick
whenever we write `foo.getScope() = bar.getScope()` for some expressions
`foo` and `bar`.

This lead to things like

```
(196s) Tuple counts for Definitions::ModuleVariable::global_variable_callnode#ff/2@5ab278 after 2m33s:
2952757013 ~0%     {2} r1 = JOIN Definitions::ModuleVariable::global_variable_callnode#ff#shared WITH Variables::Variable::getScope_dispred#ff_10#join_rhs ON FIRST 1 OUTPUT Rhs.1 'this', Lhs.1 'result'
495693     ~0%     {2} r2 = JOIN r1 WITH Variables::GlobalVariable#class#f ON FIRST 1 OUTPUT Lhs.0 'this', Lhs.1 'result'
453589     ~0%     {2} r3 = JOIN r2 WITH Definitions::ModuleVariable#f ON FIRST 1 OUTPUT Lhs.0 'this', Lhs.1 'result'
                   return r3
```

and

```
(315s) Tuple counts for Definitions::SsaSourceVariable::getAUse_dispred#ff/2@a39328 after 1m57s:
...
1785275    ~3%       {2} r24 = Definitions::ModuleVariable::global_variable_callnode#ff#shared UNION Definitions::SsaSourceVariable::getAUse_dispred#ff#shared
3008614987 ~0%       {2} r25 = JOIN r24 WITH Variables::Variable::getScope_dispred#ff_10#join_rhs ON FIRST 1 OUTPUT Rhs.1 'this', Lhs.1 'result'
127        ~1%       {2} r26 = JOIN r25 WITH Definitions::NonLocalVariable#class#f ON FIRST 1 OUTPUT Lhs.0 'this', Lhs.1 'result'
127        ~1%       {2} r27 = JOIN r26 WITH Variables::LocalVariable#f ON FIRST 1 OUTPUT Lhs.0 'this', Lhs.1 'result'
...
```

(Note the timings: 2m33s and 1m57s.)

Now we have the much more reasonable

```
(38s) Tuple counts for Definitions::ModuleVariable::global_variable_callnode#ff/2@c53031 after 42ms:
453589 ~0%     {2} r1 = JOIN Definitions::ModuleVariable::global_variable_callnode#ff#shared WITH Definitions::ModuleVariable::scope_as_global_variable#ff_10#join_rhs ON FIRST 1 OUTPUT Rhs.1 'this', Lhs.1 'result'
               return r1
```

and

```
(46s) Tuple counts for Definitions::SsaSourceVariable::getAUse_dispred#ff/2@4b19de after 375ms:
...
```

Author: tausbn

python/ql/lib/semmle/python/essa/Definitions.qll

@@ -152,17 +152,17 @@ class NonLocalVariable extends SsaSourceVariable {
   }
 
   override ControlFlowNode getAnImplicitUse() {
-    result.(CallNode).getScope().getScope*() = this.(LocalVariable).getScope()
+    result.(CallNode).getScope().getScope*() = this.scope_as_local_variable()
   }
 
   override ControlFlowNode getScopeEntryDefinition() {
     exists(Function f |
-      f.getScope+() = this.(LocalVariable).getScope() and
+      f.getScope+() = this.scope_as_local_variable() and
       f.getEntryNode() = result
     )
     or
     not this.(LocalVariable).isParameter() and
-    this.(LocalVariable).getScope().getEntryNode() = result
+    this.scope_as_local_variable().getEntryNode() = result
   }
 
   pragma[noinline]
@@ -215,12 +215,15 @@ class ModuleVariable extends SsaSourceVariable {
     )
   }
 
+  pragma[nomagic]
+  private Scope scope_as_global_variable() { result = this.(GlobalVariable).getScope() }
+
   pragma[noinline]
-  CallNode global_variable_callnode() { result.getScope() = this.(GlobalVariable).getScope() }
+  CallNode global_variable_callnode() { result.getScope() = this.scope_as_global_variable() }
 
   pragma[noinline]
   ImportMemberNode global_variable_import() {
-    result.getScope() = this.(GlobalVariable).getScope() and
+    result.getScope() = this.scope_as_global_variable() and
     import_from_dot_in_init(result.getModule(this.getName()))
   }
 
@@ -250,7 +253,7 @@ class ModuleVariable extends SsaSourceVariable {
   override ControlFlowNode getScopeEntryDefinition() {
     exists(Scope s | s.getEntryNode() = result |
       /* Module entry point */
-      this.(GlobalVariable).getScope() = s
+      this.scope_as_global_variable() = s
       or
       /* For implicit use of __metaclass__ when constructing class */
       class_with_global_metaclass(s, this)
@@ -286,13 +289,13 @@ class EscapingGlobalVariable extends ModuleVariable {
   override ControlFlowNode getAnImplicitUse() {
     result = ModuleVariable.super.getAnImplicitUse()
     or
-    result.(CallNode).getScope().getScope+() = this.(GlobalVariable).getScope()
+    result.(CallNode).getScope().getScope+() = this.scope_as_global_variable()
     or
     result = this.innerScope().getANormalExit()
   }
 
   private Scope innerScope() {
-    result.getScope+() = this.(GlobalVariable).getScope() and
+    result.getScope+() = this.scope_as_global_variable() and
     not result instanceof ImportTimeScope
   }