Add support for external trigger control

Author: nseidle

Firmware/RTK_Surveyor/Begin.ino

@@ -497,3 +497,38 @@ void beginSystemState()
       ButtonCheckTaskPriority,
       &ButtonCheckTaskHandle); //Task handle
 }
+
+//Setup the timepulse output on the PPS pin for external triggering
+//Setup TM2 time stamp input as need
+void beginExternalTriggers()
+{
+  UBX_CFG_TP5_data_t timePulseParameters;
+
+  if (i2cGNSS.getTimePulseParameters(&timePulseParameters) == false)
+    log_e("getTimePulseParameters failed!");
+
+  timePulseParameters.tpIdx = 0; // Select the TIMEPULSE pin
+
+  // While the module is _locking_ to GNSS time, turn off pulse
+  timePulseParameters.freqPeriod = 1000000; //Set the period between pulses in us
+  timePulseParameters.pulseLenRatio = 0; //Set the pulse length in us
+
+  // When the module is _locked_ to GNSS time, make it generate 1kHz
+  timePulseParameters.freqPeriodLock = settings.externalPulseTimeBetweenPulse_us; //Set the period between pulses is us
+  timePulseParameters.pulseLenRatioLock = settings.externalPulseLength_us; //Set the pulse length in us
+
+  timePulseParameters.flags.bits.active = settings.enableExternalPulse; //Make sure the active flag is set to enable the time pulse. (Set to 0 to disable.)
+  timePulseParameters.flags.bits.lockedOtherSet = 1; //Tell the module to use freqPeriod while locking and freqPeriodLock when locked to GNSS time
+  timePulseParameters.flags.bits.isFreq = 0; //Tell the module that we want to set the period
+  timePulseParameters.flags.bits.isLength = 1; //Tell the module that pulseLenRatio is a length (in us)
+  timePulseParameters.flags.bits.polarity = (uint8_t)settings.externalPulsePolarity; //Rising or failling edge type pulse
+
+  if (i2cGNSS.setTimePulseParameters(&timePulseParameters, 1000) == false)
+    log_e("setTimePulseParameters failed!");
+
+  if (settings.enableExternalHardwareEventLogging == true)
+    i2cGNSS.setAutoTIMTM2callback(&eventTriggerReceived); //Enable automatic TIM TM2 messages with callback to eventTriggerReceived
+  else
+    i2cGNSS.setAutoTIMTM2callback(NULL);
+
+}

Firmware/RTK_Surveyor/RTK_Surveyor.ino

@@ -44,9 +44,9 @@
 const int FIRMWARE_VERSION_MAJOR = 1;
 const int FIRMWARE_VERSION_MINOR = 10;
 
-#define COMPILE_WIFI //Comment out to remove all WiFi functionality
-#define COMPILE_BT //Comment out to disable all Bluetooth
-//#define ENABLE_DEVELOPER //Uncomment this line to enable special developer modes (don't check power button at startup)
+//#define COMPILE_WIFI //Comment out to remove all WiFi functionality
+//#define COMPILE_BT //Comment out to disable all Bluetooth
+#define ENABLE_DEVELOPER //Uncomment this line to enable special developer modes (don't check power button at startup)
 
 //Define the RTK board identifier:
 //  This is an int which is unique to this variant of the RTK Surveyor hardware which allows us
@@ -353,6 +353,11 @@ uint32_t lastSetupMenuChange = 0; //Auto-selects the setup menu option after 150
 uint32_t lastTestMenuChange = 0; //Avoids exiting the test menu for at least 1 second
 
 bool firstRoverStart = false; //Used to detect if user is toggling power button at POR to enter test menu
+
+bool newEventToRecord = false; //Goes true when INT pin goes high
+uint32_t triggerCount = 0; //Global copy - TM2 event counter
+uint32_t towMsR = 0; //Global copy - Time Of Week of rising edge (ms)
+uint32_t towSubMsR = 0; //Global copy - Millisecond fraction of Time Of Week of rising edge in nanoseconds
 //-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
 
 void setup()
@@ -386,6 +391,8 @@ void setup()
 
   beginAccelerometer();
 
+  beginExternalTriggers(); //Configure the time pulse output and TM2 input
+
   beginSystemState(); //Determine initial system state. Start task for button monitoring.
 
   Serial.flush(); //Complete any previous prints
@@ -396,6 +403,7 @@ void setup()
 void loop()
 {
   i2cGNSS.checkUblox(); //Regularly poll to get latest data and any RTCM
+  i2cGNSS.checkCallbacks(); //Process any callbacks: ie, eventTriggerReceived
 
   updateSystemState();
 
@@ -467,6 +475,27 @@ void updateLogs()
       }
     }
 
+    //Record any pending trigger events
+    if (newEventToRecord == true)
+    {
+      Serial.println("Recording event");
+
+      //Record trigger count with Time Of Week of rising edge (ms) and Millisecond fraction of Time Of Week of rising edge (ns)
+      char eventData[82]; //Max NMEA sentence length is 82
+      snprintf(eventData, sizeof(eventData), "%d,%d,%d", triggerCount, towMsR, towSubMsR);
+
+      char nmeaMessage[82]; //Max NMEA sentence length is 82
+      createNMEASentence(CUSTOM_NMEA_TYPE_EVENT, nmeaMessage, eventData); //textID, buffer, text
+
+      if (xSemaphoreTake(xFATSemaphore, fatSemaphore_shortWait_ms) == pdPASS)
+      {
+        ubxFile.println(nmeaMessage);
+
+        xSemaphoreGive(xFATSemaphore);
+        newEventToRecord = false;
+      }
+    }
+
     //Report file sizes to show recording is working
     if (millis() - lastFileReport > 5000)
     {

Firmware/RTK_Surveyor/States.ino

@@ -571,7 +571,7 @@ void updateSystemState()
           if (online.logging == true)
           {
             char nmeaMessage[82]; //Max NMEA sentence length is 82
-            createNMEASentence(1, 2, nmeaMessage, (char*)"CustomEvent"); //sentenceNumber, textID, buffer, text
+            createNMEASentence(CUSTOM_NMEA_TYPE_WAYPOINT, nmeaMessage, (char*)"CustomEvent"); //textID, buffer, text
             ubxFile.println(nmeaMessage);
             displayEventMarked(500); //Show 'Event Marked'
           }

Firmware/RTK_Surveyor/System.ino

@@ -756,11 +756,15 @@ boolean SFE_UBLOX_GNSS_ADD::getModuleInfo(uint16_t maxWait)
 
 //Create $GNTXT, type message complete with CRC
 //https://www.nmea.org/Assets/20160520%20txt%20amendment.pdf
-//Used for reporting a system reboot inside the log
-void createNMEASentence(uint8_t sentenceNumber, uint8_t textID, char *nmeaMessage, char *textMessage)
+//Used for recording system events (boot reason, event triggers, etc) inside the log
+void createNMEASentence(customNmeaType_e textID, char *nmeaMessage, char *textMessage)
 {
+  //Currently we don't have messages longer than 82 char max so we hardcode the sentence numbers
+  const uint8_t totalNumberOfSentences = 1;
+  const uint8_t sentenceNumber = 1;
+  
   char nmeaTxt[82]; //Max NMEA sentence length is 82
-  sprintf(nmeaTxt, "$GNTXT,01,%02d,%02d,%s*", sentenceNumber, textID, textMessage);
+  sprintf(nmeaTxt, "$GNTXT,%02d,%02d,%02d,%s*", totalNumberOfSentences, sentenceNumber, textID, textMessage);
 
   //From: http://engineeringnotes.blogspot.com/2015/02/generate-crc-for-nmea-strings-arduino.html
   byte CRC = 0; // XOR chars between '$' and '*'

Firmware/RTK_Surveyor/menuMessages.ino

@@ -384,7 +384,7 @@ void beginLogging()
           }
 
           char nmeaMessage[82]; //Max NMEA sentence length is 82
-          createNMEASentence(1, 1, nmeaMessage, rstReason); //sentenceNumber, textID, buffer, text
+          createNMEASentence(CUSTOM_NMEA_TYPE_RESET_REASON, nmeaMessage, rstReason); //textID, buffer, text
           ubxFile.println(nmeaMessage);
 
           if (reuseLastLog == true)

Firmware/RTK_Surveyor/menuPorts.ino

@@ -3,7 +3,7 @@ void menuPorts()
   if (productVariant == RTK_SURVEYOR)
     menuPortsSurveyor();
   else if (productVariant == RTK_EXPRESS || productVariant == RTK_EXPRESS_PLUS)
-    menuPortsExpress();
+    menuPortsMultiplexed();
 }
 
 //Set the baud rates for the radio and data ports
@@ -67,7 +67,7 @@ void menuPortsSurveyor()
 }
 
 //Set the baud rates for the radio and data ports
-void menuPortsExpress()
+void menuPortsMultiplexed()
 {
   while (1)
   {
@@ -100,6 +100,10 @@ void menuPortsExpress()
       Serial.print(getSerialRate(COM_PORT_UART1));
       Serial.println(F(" bps"));
     }
+    else if (settings.dataPortChannel == MUX_PPS_EVENTTRIGGER)
+    {
+      Serial.print(F("3) Configure External Triggers"));
+    }
 
     Serial.println(F("x) Exit"));
 
@@ -155,6 +159,94 @@ void menuPortsExpress()
         i2cGNSS.setSerialRate(newBaud, COM_PORT_UART1); //Set Data Port
       }
     }
+    else if (incoming == '3' && settings.dataPortChannel == MUX_PPS_EVENTTRIGGER)
+    {
+      menuPortHardwareTriggers();
+    }
+    else if (incoming == 'x')
+      break;
+    else if (incoming == STATUS_GETBYTE_TIMEOUT)
+      break;
+    else
+      printUnknown(incoming);
+  }
+
+  while (Serial.available()) Serial.read(); //Empty buffer of any newline chars
+}
+
+//Configure the behavior of the PPS and INT pins on the ZED-F9P
+//Most often used for logging events (inputs) and when external triggers (outputs) occur
+void menuPortHardwareTriggers()
+{
+  int menuTimeoutExtended = 30; //Increase time needed for complex data entry (mount point ID, ECEF coords, etc).
+
+  while (1)
+  {
+    Serial.println();
+    Serial.println(F("Menu: Port Hardware Trigger Menu"));
+
+    Serial.print(F("1) Enable External Pulse: "));
+    if (settings.enableExternalPulse == true) Serial.println(F("Enabled"));
+    else Serial.println(F("Disabled"));
+
+    if (settings.enableExternalPulse == true)
+    {
+      Serial.print(F("2) Set time between pulses: "));
+      Serial.print(settings.externalPulseTimeBetweenPulse_us / 1000.0);
+      Serial.println(F("ms"));
+
+      Serial.print(F("3) Set pulse length: "));
+      Serial.print(settings.externalPulseLength_us / 1000.0);
+      Serial.println(F("ms"));
+
+      Serial.print(F("4) Set pulse polarity: "));
+      if (settings.externalPulsePolarity == PULSE_RISING_EDGE) Serial.println(F("Rising"));
+      else Serial.println(F("Falling"));
+    }
+
+    Serial.print(F("5) Log External Events: "));
+    if (settings.enableExternalHardwareEventLogging == true) Serial.println(F("Enabled"));
+    else Serial.println(F("Disabled"));
+
+    Serial.println(F("x) Exit"));
+
+    byte incoming = getByteChoice(menuTimeout); //Timeout after x seconds
+
+    if (incoming == '1')
+    {
+      settings.enableExternalPulse ^= 1;
+    }
+    else if (incoming == '2' && settings.enableExternalPulse == true)
+    {
+      Serial.print(F("Time between pulses in milliseconds: "));
+      double pulseTime = getDouble(menuTimeoutExtended); //Timeout after x seconds
+
+      if (pulseTime != STATUS_GETNUMBER_TIMEOUT && pulseTime != STATUS_PRESSED_X)
+      {
+        settings.externalPulseTimeBetweenPulse_us = pulseTime * 1000;
+      }
+    }
+    else if (incoming == '3' && settings.enableExternalPulse == true)
+    {
+      Serial.print(F("Pulse length in milliseconds: "));
+      double pulseLength = getDouble(menuTimeoutExtended); //Timeout after x seconds
+
+      if (pulseLength != STATUS_GETNUMBER_TIMEOUT && pulseLength != STATUS_PRESSED_X)
+      {
+        settings.externalPulseLength_us = pulseLength * 1000;
+      }
+    }
+    else if (incoming == '4' && settings.enableExternalPulse == true)
+    {
+      if (settings.externalPulsePolarity == PULSE_RISING_EDGE)
+        settings.externalPulsePolarity = PULSE_FALLING_EDGE;
+      else
+        settings.externalPulsePolarity = PULSE_RISING_EDGE;
+    }
+    else if (incoming == '5')
+    {
+      settings.enableExternalHardwareEventLogging ^= 1;
+    }
     else if (incoming == 'x')
       break;
     else if (incoming == STATUS_GETBYTE_TIMEOUT)
@@ -164,4 +256,27 @@ void menuPortsExpress()
   }
 
   while (Serial.available()) Serial.read(); //Empty buffer of any newline chars
+
+  beginExternalTriggers(); //Update with new settings
+
+  if (settings.enableExternalHardwareEventLogging == true)
+    i2cGNSS.setAutoTIMTM2callback(&eventTriggerReceived); // Enable automatic TIM TM2 messages with callback to eventMessageReceived
+  else
+    i2cGNSS.setAutoTIMTM2callback(NULL);
+}
+
+void eventTriggerReceived(UBX_TIM_TM2_data_t ubxDataStruct)
+{
+  // It is the rising edge of the sound event (TRIG) which is important
+  // The falling edge is less useful, as it will be "debounced" by the loop code
+  if (ubxDataStruct.flags.bits.newRisingEdge) // 1 if a new rising edge was detected
+  {
+    Serial.println("Rising Edge Event");
+
+    triggerCount = ubxDataStruct.count;
+    towMsR = ubxDataStruct.towMsR; // Time Of Week of rising edge (ms)
+    towSubMsR = ubxDataStruct.towSubMsR; // Millisecond fraction of Time Of Week of rising edge in nanoseconds
+
+    newEventToRecord = true;
+  }
 }

Firmware/RTK_Surveyor/settings.h

@@ -70,6 +70,21 @@ typedef enum
   COORD_TYPE_GEOGRAPHIC,
 } coordinateType_e;
 
+//User can select output pulse as either falling or rising edge
+typedef enum
+{
+  PULSE_FALLING_EDGE = 0,
+  PULSE_RISING_EDGE,
+} pulseEdgeType_e;
+
+//Custom NMEA sentence types output to the log file
+typedef enum
+{
+  CUSTOM_NMEA_TYPE_RESET_REASON = 0,
+  CUSTOM_NMEA_TYPE_WAYPOINT,
+  CUSTOM_NMEA_TYPE_EVENT,
+} customNmeaType_e;
+
 //Freeze and blink LEDs if we hit a bad error
 typedef enum
 {
@@ -291,6 +306,11 @@ struct struct_settings {
   bool autoIMUmountAlignment = true; //Allows unit to automatically establish device orientation in vehicle
   bool enableResetDisplay = false;
   uint8_t resetCount = 0;
+  bool enableExternalPulse = false; //Send pulse once lock is achieved
+  uint32_t externalPulseTimeBetweenPulse_us = 500000; //us between pulses, max of 65s
+  uint32_t externalPulseLength_us = 100000; //us length of pulse
+  pulseEdgeType_e externalPulsePolarity = PULSE_RISING_EDGE; //Pulse rises for pulse length, then falls
+  bool enableExternalHardwareEventLogging = false; //Log when INT/TM2 pin goes low
 } settings;
 
 //Monitor which devices on the device are on or offline.